home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
The 640 MEG Shareware Studio 2
/
The 640 Meg Shareware Studio CD-ROM Volume II (Data Express)(1993).ISO
/
door
/
dparm12.zip
/
CALLBACK.BAT
next >
Wrap
DOS Batch File
|
1992-12-06
|
2KB
|
81 lines
rem **************************
rem ****** CALLBACK.BAT ******
rem **************************
rem ** DOS local call-back door; uses DOORPARM.COM & PASSPARM.BAT **
rem passed variables:
rem %1 = comport, %2 = baud, %3 = fname, %4 = lname,
rem %5 = voice #, %6 = modem #, %7 = seclevel, %8 = mins remaining,
rem %9 = color, %10 = error correction
@echo off
set dummy1=
rem (frees extra environment space in WC! shell)
rem ("prompt" with no parameters works, also)
rem ***********************
if "%1" == "COM0:" goto end
rem disable local usage
rem ***********************
echo %1
echo ** processing local callback for %3 %4
echo ** initializing environment variables
set comport=%1
set dialout=%6
if %6 == N/A set dialout=%5
echo %3 %4 callback at %dialout% >> \wc30\doors\callback.log
echo ** stripping area code and "-" from target number
for %%Y in (/%dialout%) do set dialout=%%Y
for %%Y in (/%dialout%) do set dialout=%%Y
for %%Y in (/%dialout%) do set dialout=%%Y
for %%Y in (/%dialout%) do set dialout=%%Y
echo ** sending instructions to the user
rem PAUZ.EXE is found in PAUZ15.ZIP
echo > %comport%
if %9 == GR echo
> %comport%
echo Welcome to CloudBase Local Callback! > %comport%
echo > %comport%
\wc30\utils\pauz space 1 >nul
if %9 == GR echo
> %comport%
echo You will be called at %dialout%... > %comport%
\wc30\utils\pauz space 1 >nul
if %9 == GR echo
> %comport%
echo When the phone rings, type ATA (in capitals), then press return. > %comport%
\wc30\utils\pauz space 1 >nul
if %9 == GR echo
> %comport%
echo Please do NOT pick up and say Hello. > %comport%
echo > %comport%
\wc30\utils\pauz space 4 >nul
if %9 == GR echo
> %comport%
echo Terminating connection... > %comport%
if %9 == GR echo
> %comport%
\wc30\utils\pauz space 1 >nul
echo ** dropping carrier
rem DTR.COM is found in DOSMODEM.ZIP
\wc30\utils\dtr %comport% off
\wc30\utils\pauz space 2 >nul
\wc30\utils\dtr %comport% on
\wc30\utils\pauz space 8 >nul
echo ** sending modem ATZ
echo ATZ > %comport%
\wc30\utils\pauz space 2 >nul
echo ** checking remote for error correction
shift
if %9 == N echo ** disabling call-out error correction
if %9 == N echo AT&M0 > %comport%
if %9 == N \wc30\utils\pauz space 2 >nul
echo ** dialing %dialout%
echo ATB1DT %dialout% > %comport%
\wc30\utils\pauz space 30
set comport=
set dialout=
:end